Transformer une figure fermée en path

Tout ce qui concerne l'utilisation ou l'installation d'Asymptote.

Modérateur: gdm_asy

Règles du forum
Merci d'éviter le style SMS dans vos messages et de penser à utiliser la fonction Recherche avant de poster un message. Pour joindre des fichiers à vos messages, consulter ce sujet.
> Penser à utiliser les balises Code pour poster du code.

Transformer une figure fermée en path

Messagepar alekhine » Mercredi 20 Mai 2009, 10:13

Bonjour à tous.

Je souhaiterais transformer une figure fermée en path afin de la colorier.
J'ai construit une figure fermée complexe (un triskell) mais tous mes essais pour colorier l'intérieur se sont soldés par un échec. Elle est constituée d'arcs de cercles.
Je ne donne pas le code car il est long, mais si vous en avez besoin pour me répondre, je le posterai.

Merci.
Dernière édition par alekhine le Jeudi 21 Mai 2009, 15:25, édité 1 fois.
alekhine
Kilo-utilisateur
 
Messages: 225
Inscription: Samedi 18 Août 2007, 20:57
Localisation: Caen
Statut actuel: Actif et salarié | Enseignant

Publicité

Re: [asy] transformer une figure fermée en path

Messagepar OG » Mercredi 20 Mai 2009, 10:16

Bonjour

Je veux bien le code.

O.G.
OG
Modérateur
 
Messages: 2258
Inscription: Lundi 12 Mars 2007, 11:20
Localisation: Rouen
Statut actuel: Actif et salarié | Maître de conférence

Re: [asy] transformer une figure fermée en path

Messagepar alekhine » Mercredi 20 Mai 2009, 11:07

Le voilà

Code: Tout sélectionner
import geometrie;
unitsize(1cm);
point [] a1,a2;
point o=(0,0);
real rayon1=9, rayon2=10;
pen crayon=0.1bp+black;
a1[0]=(0,rayon1);
a2[0]=(0,rayon2);
circle cercle1=circle(o,rayon1), cercle2=circle(o,rayon2), cerclebis=circle(0,rayon2-0.5);
transform rota60=rotate(-60,o), rota120=rotate(-120,o);

for (int i=0; i<=5; ++i)
    {a1[i+1]=rota60*a1[i];
    a2[i+1]=rota60*a2[i];};
   
line ligne1=line(a1[1],a1[5]), ligne2=line(a2[1],a2[5]), verticale=line(o,a1[0]);
point[] b,c,d,e;
b[0]=intersectionpoint(verticale,ligne1);
c[0]=intersectionpoint(verticale,ligne2);
d[0]=c[0]+(0.5,0);
e[0]=b[0]+(0.5,0);

for (int i=0; i<=2; ++i)
    {b[i+1]=rota120*b[i];
     c[i+1]=rota120*c[i];
     d[i+1]=rota120*d[i];
     e[i+1]=rota120*e[i];};
     
line [] cotri;

for (int i=0; i<=1; ++i)
    {cotri[i]=line(b[i],b[i+1]);}
   
cotri[2]=line(b[0],b[2]);
point m=intersectionpoint(verticale,cotri[1])-(0.5,0);

line  lignecarre1=line(d[2],c[2]),
      lignecarre2=line(c[2],b[2]),
      lignecarre3=line(b[2],e[2]),
      lignecarre4=line(e[2],d[2]);

circle spirale1=circle(b[2],abs(m-b[2])),
   spirale2=circle(b[2],abs(m-b[2])+1);
   
arc[] arc1, arc2, arc3;

point[] s1=intersectionpoints(spirale1,lignecarre3);
arc1[1]=arc(spirale1,m,s1[1]);
draw(arc1[1],crayon);

point[] s2=intersectionpoints(spirale2,cotri[2]),
   s3=intersectionpoints(spirale2,lignecarre3);
arc1[2]=arc(spirale2,s2[1],s3[1]);
draw(arc1[2],crayon);

circle spirale3=circle(e[2],abs(s3[1]-e[2]));
point[] s4=intersectionpoints(spirale3,lignecarre4);
arc1[3]=arc(spirale3,s3[1],s4[0]);
draw(arc1[3],crayon);

circle spirale4=circle(e[2],abs(e[2]-s1[1]));
point[] s5=intersectionpoints(spirale4,lignecarre4);
arc1[4]=arc(spirale4,s1[1],s5[0]);
draw(arc1[4],crayon);

circle spirale5=circle(d[2],abs(d[2]-s4[0]));
point[] s6=intersectionpoints(spirale5,lignecarre1);
arc1[5]=arc(spirale5,s4[0],s6[0]);
draw(arc1[5],crayon);

circle spirale6=circle(d[2],abs(d[2]-s5[0]));
point[] s7=intersectionpoints(spirale6,lignecarre1);
arc1[6]=arc(spirale6,s5[0],s7[0]);
draw(arc1[6],crayon);

circle spirale7=circle(c[2],abs(c[2]-s6[0]));
point[] s8=intersectionpoints(spirale7,lignecarre2);
arc1[7]=arc(spirale7,s6[0],s8[1]);
draw(arc1[7],crayon);

circle spirale8=circle(c[2],abs(c[2]-s7[0]));
point[] s9=intersectionpoints(spirale8,lignecarre2);
arc1[8]=arc(spirale8,s7[0],s9[1]);
draw(arc1[8],crayon);

circle spirale9=circle(b[2],abs(b[2]-s8[1]));
point[] s10=intersectionpoints(spirale9,lignecarre3);
arc1[9]=arc(spirale9,s8[1],s10[1]);
draw(arc1[9],crayon);

circle spirale10=circle(b[2],abs(b[2]-s9[1]));
point[] s11=intersectionpoints(spirale10,lignecarre3);
arc1[10]=arc(spirale10,s9[1],s11[1]);
draw(arc1[10],crayon);

circle spirale11=circle(e[2],abs(e[2]-s10[1]));
point[] s12=intersectionpoints(spirale11,lignecarre4);
arc1[11]=arc(spirale11,s10[1],s12[0]);
draw(arc1[11],crayon);

circle spirale12=circle(e[2],abs(e[2]-s11[1]));
point[] s13=intersectionpoints(spirale12,lignecarre4);

circle spirale13=circle(d[2],abs(d[2]-s12[0]));
point[] s14=intersectionpoints(spirale13,lignecarre1);
arc1[13]=arc(spirale13,s12[0],s14[0]);
draw(arc1[13],crayon);

circle spirale14=circle(c[2],abs(c[2]-s14[0]));
point[] s15=intersectionpoints(spirale12,spirale14);
arc1[14]=arc(spirale14,s14[0],s15[1]);
draw(arc1[14],crayon);

arc1[12]=arc(spirale12,s11[1],s15[1]);
draw(arc1[12],crayon);

for (int i=1; i<=14; ++i)
    {arc2[i]=rota120*arc1[i];
    draw(arc2[i],crayon);
    arc3[i]=rota120*arc2[i];
    draw(arc3[i],crayon);};
Dernière édition par alekhine le Mercredi 20 Mai 2009, 12:09, édité 2 fois.
alekhine
Kilo-utilisateur
 
Messages: 225
Inscription: Samedi 18 Août 2007, 20:57
Localisation: Caen
Statut actuel: Actif et salarié | Enseignant

Re: [asy] transformer une figure fermée en path

Messagepar GMaths » Mercredi 20 Mai 2009, 11:55

quelques commentaires :
- tu donnes deux fois le même code ;-)
- je vois "geometrie"... mais apparemment d'après le code... il n'y a rien qui ne soit incompatible avec l'extension officielle "geometry".
- beaucoup de draw et de chemins distincts... je pense qu'il faut tout revoir pour avoir un seul path : quel est l'intérêt de dessiner les arcs séparément ? Un seul path, ce sera plus simple pour colorier à l'intérieur.

Je peux proposer une modification mais peut-être qu'OG est déjà en train de te le faire. :mrgreen:
Au cas où, ce ne serait pas le cas... et pour me faire plaisir... je te proposerai une version tout à l'heure si Olivier ne m'a pas précédé. :)
GMaths
Exa-utilisateur
 
Messages: 2031
Inscription: Lundi 01 Octobre 2007, 09:20
Statut actuel: Actif et salarié | Enseignant

Re: [asy] transformer une figure fermée en path

Messagepar alekhine » Mercredi 20 Mai 2009, 12:07

Merci pour les commentaires et pour la proposition d'améliorer le code.
Je savais que je ferais bondir en présentant ce code. :D
En effet je suis une vraie bille en programmation et ma conaissance d'Asymptote se limite à l'étude des exemples de P.Ivaldi. D'ailleurs l'extension geometrie est simplement le nom que j'utilise pour son extension geometry_dev.
Je suis impatient de voir comment on peut faire cette figure avec un seul path.
alekhine
Kilo-utilisateur
 
Messages: 225
Inscription: Samedi 18 Août 2007, 20:57
Localisation: Caen
Statut actuel: Actif et salarié | Enseignant

Re: [asy] transformer une figure fermée en path

Messagepar GMaths » Mercredi 20 Mai 2009, 13:00

alekhine a écrit:D'ailleurs l'extension geometrie est simplement le nom que j'utilise pour son extension geometry_dev.

Charge la dernière version d'Asymptote
et tu pourras dorénavant de contenter d'écrire geometry car l'extension de Philippe a intégré la distribution officielle.

alekhine a écrit:Je suis impatient de voir comment on peut faire cette figure avec un seul path.

Voilà un premier jet ci-dessous.

Je ne me suis absolument pas préoccupé de la première partie de ton code...
Je n'ai pas réfléchi du tout si on pouvait être plus efficace pour la recherche des points utiles
Je dirai même que je ne connais pas le procédé...

donc je me suis uniquement contenté de mettre tes arcs dans le bon ordre pour former un seul path
et pouvoir colorier.

Code: Tout sélectionner
import geometry;
unitsize(1cm);
point [] a1,a2;
point o=(0,0);
real rayon1=9, rayon2=10;
pen crayon=0.1bp+black;
a1[0]=(0,rayon1);
a2[0]=(0,rayon2);
circle cercle1=circle(o,rayon1), cercle2=circle(o,rayon2), cerclebis=circle(0,rayon2-0.5);
transform rota60=rotate(-60,o), rota120=rotate(-120,o);

for (int i=0; i<=5; ++i)
{a1[i+1]=rota60*a1[i];
a2[i+1]=rota60*a2[i];};
   
line ligne1=line(a1[1],a1[5]), ligne2=line(a2[1],a2[5]), verticale=line(o,a1[0]);
point[] b,c,d,e;
b[0]=intersectionpoint(verticale,ligne1);
c[0]=intersectionpoint(verticale,ligne2);
d[0]=c[0]+(0.5,0);
e[0]=b[0]+(0.5,0);

for (int i=0; i<=2; ++i)
{b[i+1]=rota120*b[i];
 c[i+1]=rota120*c[i];
 d[i+1]=rota120*d[i];
 e[i+1]=rota120*e[i];};
 
line [] cotri;

for (int i=0; i<=1; ++i)
{cotri[i]=line(b[i],b[i+1]);}
   
cotri[2]=line(b[0],b[2]);
point m=intersectionpoint(verticale,cotri[1])-(0.5,0);

line  lignecarre1=line(d[2],c[2]),
      lignecarre2=line(c[2],b[2]),
      lignecarre3=line(b[2],e[2]),
      lignecarre4=line(e[2],d[2]);

circle spirale1=circle(b[2],abs(m-b[2])),
       spirale2=circle(b[2],abs(m-b[2])+1);
point[] s1=intersectionpoints(spirale1,lignecarre3),
        s2=intersectionpoints(spirale2,cotri[2]),
        s3=intersectionpoints(spirale2,lignecarre3);
circle spirale3=circle(e[2],abs(s3[1]-e[2]));
point[] s4=intersectionpoints(spirale3,lignecarre4);
circle spirale4=circle(e[2],abs(e[2]-s1[1]));
point[] s5=intersectionpoints(spirale4,lignecarre4);
circle spirale5=circle(d[2],abs(d[2]-s4[0]));
point[] s6=intersectionpoints(spirale5,lignecarre1);
circle spirale6=circle(d[2],abs(d[2]-s5[0]));
point[] s7=intersectionpoints(spirale6,lignecarre1);
circle spirale7=circle(c[2],abs(c[2]-s6[0]));
point[] s8=intersectionpoints(spirale7,lignecarre2);
circle spirale8=circle(c[2],abs(c[2]-s7[0]));
point[] s9=intersectionpoints(spirale8,lignecarre2);
circle spirale9=circle(b[2],abs(b[2]-s8[1]));
point[] s10=intersectionpoints(spirale9,lignecarre3);
circle spirale10=circle(b[2],abs(b[2]-s9[1]));
point[] s11=intersectionpoints(spirale10,lignecarre3);
circle spirale11=circle(e[2],abs(e[2]-s10[1]));
point[] s12=intersectionpoints(spirale11,lignecarre4);
circle spirale12=circle(e[2],abs(e[2]-s11[1]));
point[] s13=intersectionpoints(spirale12,lignecarre4);
circle spirale13=circle(d[2],abs(d[2]-s12[0]));
point[] s14=intersectionpoints(spirale13,lignecarre1);
circle spirale14=circle(c[2],abs(c[2]-s14[0]));
point[] s15=intersectionpoints(spirale12,spirale14);


guide g=arc(spirale2,s2[1],s3[1])
        --arc(spirale3,s3[1],s4[0])
        --arc(spirale5,s4[0],s6[0])
        --arc(spirale7,s6[0],s8[1])
        --arc(spirale9,s8[1],s10[1])
        --arc(spirale11,s10[1],s12[0])
        --arc(spirale13,s12[0],s14[0])
        --arc(spirale14,s14[0],s15[1])
        --reverse(arc(spirale12,s11[1],s15[1]))
        --reverse(arc(spirale10,s9[1],s11[1]))
        --reverse(arc(spirale8,s7[0],s9[1]))
        --reverse(arc(spirale6,s5[0],s7[0]))
        --reverse(arc(spirale4,s1[1],s5[0]))
        --reverse(arc(spirale1,m,s1[1]));

path triskell =rota120^2*g--rota120*g--g--cycle;
       
filldraw(triskell,paleblue,2bp+red);
GMaths
Exa-utilisateur
 
Messages: 2031
Inscription: Lundi 01 Octobre 2007, 09:20
Statut actuel: Actif et salarié | Enseignant

Re: [asy] transformer une figure fermée en path

Messagepar alekhine » Mercredi 20 Mai 2009, 13:12

Merci beaucoup c'est exactement ce que je voulais. En fait je ne connaissais pas la fonction guide :oops: .
Quelle est la dernière version d'asymptote ? Moi j'ai la 1.70.
alekhine
Kilo-utilisateur
 
Messages: 225
Inscription: Samedi 18 Août 2007, 20:57
Localisation: Caen
Statut actuel: Actif et salarié | Enseignant

Re: [asy] transformer une figure fermée en path

Messagepar OG » Mercredi 20 Mai 2009, 13:21

Re

Le dessin est joli. Je vais laisser Gaëtan s'exprimer, vu qu'il a déjà
écrit le code et qu'il attend. J'ai quelques trucs à faire avant de pouvoir
me consacer à ton dessin et comme je ne fais pas souvent du Asymptote
ça risque d'être long.

On peut construire un seul path à partir de plusieurs path,
il suffit d'écrire un truc du genre
Code: Tout sélectionner
path g=g1--g2;

ou
Code: Tout sélectionner
path g=g1..g2;

Code: Tout sélectionner
import geometry;
unitsize(1cm);
point [] a1,a2;
point o=(0,0);
real rayon1=9, rayon2=10;
pen crayon=0.1bp+black;
a1[0]=(0,rayon1);
a2[0]=(0,rayon2);
circle cercle1=circle(o,rayon1), cercle2=circle(o,rayon2), cerclebis=circle(0,rayon2-0.5);
transform rota60=rotate(-60,o), rota120=rotate(-120,o);

for (int i=0; i<=5; ++i)
    {a1[i+1]=rota60*a1[i];
    a2[i+1]=rota60*a2[i];};
   
line ligne1=line(a1[1],a1[5]), ligne2=line(a2[1],a2[5]), verticale=line(o,a1[0]);
point[] b,c,d,e;
b[0]=intersectionpoint(verticale,ligne1);
c[0]=intersectionpoint(verticale,ligne2);
d[0]=c[0]+(0.5,0);
e[0]=b[0]+(0.5,0);

for (int i=0; i<=2; ++i)
    {b[i+1]=rota120*b[i];
     c[i+1]=rota120*c[i];
     d[i+1]=rota120*d[i];
     e[i+1]=rota120*e[i];};
     
line [] cotri;

for (int i=0; i<=1; ++i)
    {cotri[i]=line(b[i],b[i+1]);}
   
cotri[2]=line(b[0],b[2]);
point m=intersectionpoint(verticale,cotri[1])-(0.5,0);

line  lignecarre1=line(d[2],c[2]),
      lignecarre2=line(c[2],b[2]),
      lignecarre3=line(b[2],e[2]),
      lignecarre4=line(e[2],d[2]);

circle spirale1=circle(b[2],abs(m-b[2])),
   spirale2=circle(b[2],abs(m-b[2])+1);
   
arc[] arc1, arc2, arc3;

point[] s1=intersectionpoints(spirale1,lignecarre3);
arc1[1]=arc(spirale1,m,s1[1]);

point[] s2=intersectionpoints(spirale2,cotri[2]),
   s3=intersectionpoints(spirale2,lignecarre3);
arc1[2]=arc(spirale2,s2[1],s3[1]);

circle spirale3=circle(e[2],abs(s3[1]-e[2]));
point[] s4=intersectionpoints(spirale3,lignecarre4);
arc1[3]=arc(spirale3,s3[1],s4[0]);

circle spirale4=circle(e[2],abs(e[2]-s1[1]));
point[] s5=intersectionpoints(spirale4,lignecarre4);
arc1[4]=arc(spirale4,s1[1],s5[0]);

circle spirale5=circle(d[2],abs(d[2]-s4[0]));
point[] s6=intersectionpoints(spirale5,lignecarre1);
arc1[5]=arc(spirale5,s4[0],s6[0]);

circle spirale6=circle(d[2],abs(d[2]-s5[0]));
point[] s7=intersectionpoints(spirale6,lignecarre1);
arc1[6]=arc(spirale6,s5[0],s7[0]);

circle spirale7=circle(c[2],abs(c[2]-s6[0]));
point[] s8=intersectionpoints(spirale7,lignecarre2);
arc1[7]=arc(spirale7,s6[0],s8[1]);

circle spirale8=circle(c[2],abs(c[2]-s7[0]));
point[] s9=intersectionpoints(spirale8,lignecarre2);
arc1[8]=arc(spirale8,s7[0],s9[1]);

circle spirale9=circle(b[2],abs(b[2]-s8[1]));
point[] s10=intersectionpoints(spirale9,lignecarre3);
arc1[9]=arc(spirale9,s8[1],s10[1]);

circle spirale10=circle(b[2],abs(b[2]-s9[1]));
point[] s11=intersectionpoints(spirale10,lignecarre3);
arc1[10]=arc(spirale10,s9[1],s11[1]);

circle spirale11=circle(e[2],abs(e[2]-s10[1]));
point[] s12=intersectionpoints(spirale11,lignecarre4);
arc1[11]=arc(spirale11,s10[1],s12[0]);

circle spirale12=circle(e[2],abs(e[2]-s11[1]));
point[] s13=intersectionpoints(spirale12,lignecarre4);

circle spirale13=circle(d[2],abs(d[2]-s12[0]));
point[] s14=intersectionpoints(spirale13,lignecarre1);
arc1[13]=arc(spirale13,s12[0],s14[0]);

circle spirale14=circle(c[2],abs(c[2]-s14[0]));
point[] s15=intersectionpoints(spirale12,spirale14);
arc1[14]=arc(spirale14,s14[0],s15[1]);

arc1[12]=arc(spirale12,s11[1],s15[1]);

path g=arc1[2]--arc1[3]--arc1[5]--arc1[7]--arc1[9]--arc1[11]--arc1[13]--arc1[14]--reverse(arc1[12])--reverse(arc1[10])--reverse(arc1[8])--reverse(arc1[6])--reverse(arc1[4])--reverse(arc1[1]);

path gg=rota120*g--g--rotate(-240,o)*g..cycle;
draw(gg);
filldraw(gg);


Ce qui ressemble à la solution de Gaëtan, sauf que j'utilise un path et non pas un guide,
ce qui pourrait provoquer des désagréments dans certains cas.

O.G.
OG
Modérateur
 
Messages: 2258
Inscription: Lundi 12 Mars 2007, 11:20
Localisation: Rouen
Statut actuel: Actif et salarié | Maître de conférence

Re: [asy] transformer une figure fermée en path

Messagepar GMaths » Mercredi 20 Mai 2009, 13:43

alekhine a écrit:Merci beaucoup c'est exactement ce que je voulais. En fait je ne connaissais pas la fonction guide :oops: .

C'est inutile ici : tu peux remplacer par path.

Pour connaitre la différence... je t'invite à lire la page 34 ici : http://asymptote.sourceforge.net/asymptote.pdf

Et si tu ne trouves pas cela clair... n'hésite pas ensuite à réclamer un exemple.

alekhine a écrit:Quelle est la dernière version d'asymptote ? Moi j'ai la 1.70.
Depuis la 1.71, l'extension de Philippe est intégrée.
On en est à la 1.73... mais demain on sera peut-être à la 1.74.
Il faut donc regarder régulièrement sur le site officiel.
GMaths
Exa-utilisateur
 
Messages: 2031
Inscription: Lundi 01 Octobre 2007, 09:20
Statut actuel: Actif et salarié | Enseignant

Re: [asy] transformer une figure fermée en path

Messagepar alekhine » Mercredi 20 Mai 2009, 13:50

Merci pour vos réponses.
Ca permet d'améliorer mes connaissances d'Asymptote.
alekhine
Kilo-utilisateur
 
Messages: 225
Inscription: Samedi 18 Août 2007, 20:57
Localisation: Caen
Statut actuel: Actif et salarié | Enseignant

Re: [asy] transformer une figure fermée en path

Messagepar GMaths » Mercredi 20 Mai 2009, 13:56

OG a écrit:... sauf que j'utilise un path et non pas un guide,
ce qui pourrait provoquer des désagréments dans certains cas.

J'ai tendance à utiliser guide tant que le chemin voulu n'est pas fini.
Pas parce que je pensais que c'était nécessaire mais parce que j'aime l'idée que le path soit le chemin complet.
Et comme je ne lis qu'avec --, je ne pensais pas que cela pouvait poser problème : je pensais que dès lors ou tu lies avec --, même si tu diffères le calcul du chemin avec guide, il n'y aurait pas de raccords bizarres.

Mais tu as bien raison : c'est vraiment inutile de toute façon d'utiliser guide dans ce cas.
GMaths
Exa-utilisateur
 
Messages: 2031
Inscription: Lundi 01 Octobre 2007, 09:20
Statut actuel: Actif et salarié | Enseignant

Re: [asy] transformer une figure fermée en path

Messagepar alekhine » Mercredi 20 Mai 2009, 16:26

Merci pour le lien.
Je suis en train de me familiariser avec buildcycle, mais son comportement n'est pas très clair. Le path obtenu est toujours une surprise !
alekhine
Kilo-utilisateur
 
Messages: 225
Inscription: Samedi 18 Août 2007, 20:57
Localisation: Caen
Statut actuel: Actif et salarié | Enseignant

Re: [asy] transformer une figure fermée en path

Messagepar GMaths » Mercredi 20 Mai 2009, 16:29

alekhine a écrit:Merci pour le lien.
Je suis en train de me familiariser avec buildcycle, mais son comportement n'est pas très clair. Le path obtenu est toujours une surprise !

C'est pour cela que j'ai fait cela :

http://www.marris.org/asymptote/Contours_Domaines/index.html#fig0006

;-)
GMaths
Exa-utilisateur
 
Messages: 2031
Inscription: Lundi 01 Octobre 2007, 09:20
Statut actuel: Actif et salarié | Enseignant

Re: [asy] transformer une figure fermée en path

Messagepar alekhine » Mercredi 20 Mai 2009, 16:32

Alors là je suis impardonnable ! En effetça fait longtemps que j'ai mis ce site en marque-ta-page et je l'utilise à chaque fois que je dois faire des figures sous asymptote. C'est grâce à ce site et à celui de P.Ivaldi que je peux utiliser asy.
alekhine
Kilo-utilisateur
 
Messages: 225
Inscription: Samedi 18 Août 2007, 20:57
Localisation: Caen
Statut actuel: Actif et salarié | Enseignant

Re: [asy] transformer une figure fermée en path

Messagepar GMaths » Mercredi 20 Mai 2009, 16:39

alekhine a écrit:Alors là je suis impardonnable ! En effetça fait longtemps que j'ai mis ce site en marque-ta-page et je l'utilise à chaque fois que je dois faire des figures sous asymptote. C'est grâce à ce site et à celui de P.Ivaldi que je peux utiliser asy.


Et bien moi, j'ai appris avec le site de Philippe...
... et plus tard d'autres apprendront avec le site sur Asymptote que tu vas faire... :mrgreen:

Je dis cela... mais j'ai en projet une nouvelle structure avec gestion des auteurs des images proposées
(un aperçu de mon premier jet : http://asy.gmaths.net/asy/
mais je vais tout reprendre fin juin... pour gérer cela par base de données).

... donc continue à t'entrainer
continue à faire de jolies figures...

et elles seront les bienvenues. :D
GMaths
Exa-utilisateur
 
Messages: 2031
Inscription: Lundi 01 Octobre 2007, 09:20
Statut actuel: Actif et salarié | Enseignant

Re: [asy] transformer une figure fermée en path

Messagepar alekhine » Mercredi 20 Mai 2009, 16:55

Ce serait avec plaisir. Mais pour ça il faudrait que j'apprenne à faire des codes plus propres pour être exploitables.
alekhine
Kilo-utilisateur
 
Messages: 225
Inscription: Samedi 18 Août 2007, 20:57
Localisation: Caen
Statut actuel: Actif et salarié | Enseignant

Re: [asy] transformer une figure fermée en path

Messagepar GMaths » Mercredi 20 Mai 2009, 17:04

alekhine a écrit:Ce serait avec plaisir. Mais pour ça il faudrait que j'apprenne à faire des codes plus propres pour être exploitables.

C'est en demandant et avec du temps que l'on apprend...

Moi j'appelais Philippe à l'aide avant... maintenant, je ne le dérange plus (car il est très pris et délaisse Asymptote pour un nouveau grand projet)... mais je continue à demander de l'aide, en très mauvais anglais, au grand manitou John Bowman
sur le forum du site officiel : http://sourceforge.net/forum/forum.php?forum_id=409349
Donc tu peux demander de l'aide ici... et si tu demandes des choses compliquées que les membres "asymptotiens" de mathematex ne savent pas faire, il suffira de se mettre à l'anglais pour avoir la réponse. ;-)
GMaths
Exa-utilisateur
 
Messages: 2031
Inscription: Lundi 01 Octobre 2007, 09:20
Statut actuel: Actif et salarié | Enseignant


Retourner vers Asymptote

 


  • Articles en relation
    Réponses
    Vus
    Dernier message

Qui est en ligne

Utilisateurs parcourant ce forum: Aucun utilisateur enregistré et 2 invités