Dessins pour fonctions continues

Tout ce qui concerne l'utilisation ou l'installation d'Asymptote.

Modérateur: gdm_asy

Règles du forum
Merci d'éviter le style SMS dans vos messages et de penser à utiliser la fonction Recherche avant de poster un message. Pour joindre des fichiers à vos messages, consulter ce sujet.
> Penser à utiliser les balises Code pour poster du code.

Dessins pour fonctions continues

Messagepar paspythagore » Lundi 09 Septembre 2013, 20:14

Bonjour.
Je ne connais pas les logiciels de dessins pour intégrer 2 dessins dans un document latex. Je ne sais pas non plus si asymptote est le mieux adapté. Est ce que quelqu'un aurait le temps de faire 2 dessins pour compiler avec du pdflatex représentant la définition de la continuité d'une fonction avec des boules :
$\forall\varepsilon>0,\exists\eta>0,f\Big(B(x,\eta)\Big)\subset\Big(f(x),\varepsilon\Big)$

Merci de votre aide.

2 dessins sur le modèle des PJ.

220px-Exemple_fonction_non_continue.png
220px-Exemple_fonction_non_continue.png (13.2 Kio) Vu 709 fois
Fichiers joints
Exemple_fonction_continue.png
Exemple_fonction_continue.png (5.86 Kio) Vu 709 fois
paspythagore
Exa-utilisateur
 
Messages: 2287
Inscription: Mercredi 19 Novembre 2008, 15:35
Statut actuel: Post-bac

Publicité

Re: dessins pour fonctions continues

Messagepar balf » Lundi 09 Septembre 2013, 23:12

Je ne sais pas me servir d'Asymptote, mais les dessins ont été clairement faits avec pstricks, et ça, je sais faire. Ça urge ? Faut-il les mêmes couleurs ?

B.A.
balf
Zetta-utilisateur
 
Messages: 3656
Inscription: Mercredi 02 Janvier 2008, 23:18
Statut actuel: Actif et salarié | Maître de conférence

Re: dessins pour fonctions continues

Messagepar maurice » Mardi 10 Septembre 2013, 04:30

Bonjour,

f4dd56b98168f0453d40f72409976545.png

Code: Tout sélectionner
import graph;
unitsize(1cm);

// Les axes
limits((0,5), (0,5));
xaxis(Label("$x$", align=N), Ticks(NoZero, Step=1, step=0, end=false, endlabel=false), Arrow);
yaxis(Label("$y$", align=W), Ticks(NoZero, Step=1, step=0, end=false, endlabel=false), Arrow);

// La zone verte
path p=box((0,2.5), (5,3.5));
filldraw(p, green, green);

// pointillés et labels
draw((0,3)--(5,3), blue+dashed);
draw((2,3.5)--(2,0), blue+dashed);
draw((0,2)--(2,2), blue+dashed);
draw((3,2.5)--(3,3.5), Arrows);
label("\small $f(2)+\varepsilon$", (3, 3.25), E);
label("\small $f(2)-\varepsilon$", (3, 2.75), E);

// La fonction
pair p1=(0,1), p2=(2,2), p3=(2,3), p4=(5,5);
draw(p1--p2^^p3--p4, bp+red);
dot(p1^^p3^^p4, 8bp+red);
dot(p2, 2bp+red, UnFill);


7a1e89949bfce9d7b455fddd9938b9de.png

Code: Tout sélectionner
import graph;
import patterns;
unitsize(1cm);

// Les axes
limits((0,5), (0,5));
xaxis(Label("$x$", align=N), Ticks(NoZero, Step=1, step=0, end=false, endlabel=false), Arrow);
yaxis(Label("$y$", align=E), Ticks(NoZero, Step=1, step=0, end=false, endlabel=false), Arrow);

// Les zones (verte et jaune)
path p=box((0,3), (5,4));
filldraw(p, green, invisible);
path q=box((1.5,0), (2.5,3));
filldraw(q, yellow, invisible);
path r=box((1.5,3), (2.5,4));
add("hachure",hatch(H=2mm,dir=NW,1mm+yellow));
fill(r,pattern("hachure"));

// pointillés et labels
draw((0,3.5)--(5,3.5), blue+dashed);
draw((2,3.5)--(2,0), blue+dashed);
draw((3,3)--(3,4), Arrows);
label("\small $f(2)+\varepsilon$", (3, 3.75), E);
label("\small $f(2)-\varepsilon$", (3, 3.25), E);


// La fonction
pair p1=(0,4.5), p2=(2,3.5), p3=(4.5, 0);
path s=p1..p2..p3;
draw(s, bp+red);
dot(p1^^p3, 8bp+red);


dernier problème pour le crochet ouvert sur la première figure, du coup, j'ouvre un sujet ici.
Sinon, pour les fonctions discontinues, on en avait parlé ici et aussi la.

A+
maurice
Asymptote :
----> Démarrage rapide : http://cgmaths.fr/Atelier/Asymptote/Asymptote.html
----> Documentation 3D : http://www.mathco.tuxfamily.org et si ça ne marche pas, essayez la version pdf
maurice
Méga-utilisateur
 
Messages: 398
Inscription: Jeudi 25 Mars 2010, 13:49
Statut actuel: Actif et salarié | Enseignant

Re: dessins pour fonctions continues

Messagepar OG » Mardi 10 Septembre 2013, 08:11

Bonjour

Pour les crochets, j'avais jadis ajouté cette possibilité à Arrows. En reprenant le fichier de Maurice

8d90f93e7770aea417917019b717d4a0.png

Code: Tout sélectionner
import graph;

void bracket(picture pic, pair a, pair d, real s,pen p=currentpen)
{
picture opic;
pair ortd=s*(-d.y,d.x);
Draw(opic,(ortd-.5d)--(-0.5d)--0.5d--(.5d+ortd),p+solid);
add(pic,opic,a);
}
arrowbar BeginBra(real size=0, real ratiob=.3)
{
return new bool(picture pic, path g, pen p, margin margin) {
real size=size == 0 ? barsize(p) : size;
bracket(pic,point(g,0),size*dir(g,0)*I,ratiob,p);
return true;
};
}
arrowbar Bra(real size=0, real ratiob=.3)
{
return new bool(picture pic, path g, pen p, margin margin) {
int L=length(g);
real size=size == 0 ? barsize(p) : size;
bracket(pic,point(g,L),size*dir(g,L)*I,-ratiob,p);
return true;
};
}
arrowbar EndBra(real size=0, real ratiob=.3)= Bra;

arrowbar Bras(real size=0,real ratiob=.3)
{
return new bool(picture pic, path g, pen p, margin margin) {
real size=size == 0 ? barsize(p) : size;
BeginBra(size,ratiob)(pic,g,p,margin);
EndBra(size,ratiob)(pic,g,p,margin);
return true;
};
}
arrowbar BeginBra=BeginBra(),
Bra=Bra(),
EndBra=Bra(),
Bras=Bras();

unitsize(1cm);

// Les axes
limits((0,5), (0,5));
xaxis(Label("$x$", align=N), Ticks(NoZero, Step=1, step=0, end=false, endlabel=false), Arrow);
yaxis(Label("$y$", align=W), Ticks(NoZero, Step=1, step=0, end=false, endlabel=false), Arrow);

// La zone verte
path p=box((0,2.5), (5,3.5));
filldraw(p, green, green);

// pointillés et labels
draw((0,3)--(5,3), blue+dashed);
draw((2,3.5)--(2,0), blue+dashed);
draw((0,2)--(2,2), blue+dashed);
draw((3,2.5)--(3,3.5), Arrows);
label("\small $f(2)+\varepsilon$", (3, 3.25), E);
label("\small $f(2)-\varepsilon$", (3, 2.75), E);

// La fonction
pair p1=(0,1), p2=(2,2), p3=(2,3), p4=(5,5);
draw(p3--p4, bp+red);
draw(p1--p2,bp+red,(EndBra));
dot(p1^^p3^^p4, 8bp+red);



Pour le second, ajout de l'étiquette $2-\eta$

95acd8781ca65c6e239162f700134e83.png

Code: Tout sélectionner
import graph;
import patterns;
unitsize(1cm);

// Les axes
limits((0,5), (0,5));
xaxis(Label("$x$", align=N), Ticks(NoZero, Step=1, step=0, end=false, endlabel=false), Arrow);
yaxis(Label("$y$", align=E), Ticks(NoZero, Step=1, step=0, end=false, endlabel=false), Arrow);

// Les zones (verte et jaune)
path p=box((0,3), (5,4));
filldraw(p, green, invisible);
path q=box((1.5,0), (2.5,3));
filldraw(q, yellow, invisible);
path r=box((1.5,3), (2.5,4));
add("hachure",hatch(H=2mm,dir=NW,1mm+yellow));
fill(r,pattern("hachure"));
Label l1=Label("$2-\eta$");
draw(rotate(90)*l1,(2,0.7),NW);
Label l2=Label("$2+\eta$");
draw(rotate(90)*l2,(2,0.7),NE);
draw((1.5,.4)--(2.5,.4),Arrows);
// pointillés et labels
draw((0,3.5)--(5,3.5), blue+dashed);
draw((2,3.5)--(2,0), blue+dashed);
draw((3,3)--(3,4), Arrows);
label("\small $f(2)+\varepsilon$", (3, 3.75), E);
label("\small $f(2)-\varepsilon$", (3, 3.25), E);


// La fonction
pair p1=(0,4.5), p2=(2,3.5), p3=(4.5, 0);
path s=p1..p2..p3;
draw(s, bp+red);
dot(p1^^p3, 8bp+red);


Sinon, toutes les solutions graphiques permettent de faire ce genre de dessin.

O.G.
OG
Modérateur
 
Messages: 2210
Inscription: Lundi 12 Mars 2007, 11:20
Localisation: Rouen
Statut actuel: Actif et salarié | Maître de conférence

Re: dessins pour fonctions continues

Messagepar paspythagore » Mardi 10 Septembre 2013, 17:27

Merci Maurice et OG.
J'ai du mal m’exprimer, je m'en excuse. Ce que je veux, c'est deux dessins illustrant la continuité avec les boules : $\forall\varepsilon>0,\exists\eta>0,f\Big(B(x,\eta)\Big)\subset B\Big(f(x),\varepsilon\Big)$.
C'est à dire un cercle de centre $(2,0)$ et de rayon $\eta$, un cercle de centre $(2,f(2))$ et de rayon $\varepsilon$ et la partie de $f(x)$ qui est dans ce cercle surligné pour la fonction continue (plus en surligné aussi la partie de $f(B(x,\eta))$ qui n'est pas dans le cercle $(2,f(2))$.
Les cercles du dessin sont les boules de la définition.
@Maurice : merci pour les liens avec des sujets qui proposent des scripts Asymptote.
@balf : non, ça n'urge pas, j'aimerai me rentrer de manière claire et une bonne fois pour toutes cette notion de continuité avec des boules.
Dernière édition par paspythagore le Mardi 10 Septembre 2013, 20:31, édité 1 fois.
paspythagore
Exa-utilisateur
 
Messages: 2287
Inscription: Mercredi 19 Novembre 2008, 15:35
Statut actuel: Post-bac

Re: dessins pour fonctions continues

Messagepar balf » Mardi 10 Septembre 2013, 18:19

Mais ici, il ne peut y avoir de boules proprement dites puisqu'il s'agit de fonctions d'une variable. Les boules sont alors des intervalles. Ou alors, il faut prendre des fonctions de deux variables, ou des fonctions d'une seule mais à valeurs vectorielles. Ou encore faire un schéma qui a valeur symbolique.

B.A.
balf
Zetta-utilisateur
 
Messages: 3656
Inscription: Mercredi 02 Janvier 2008, 23:18
Statut actuel: Actif et salarié | Maître de conférence

Re: dessins pour fonctions continues

Messagepar paspythagore » Mardi 10 Septembre 2013, 20:33

Un schéma à valeur symbolique m'aiderait beaucoup.
paspythagore
Exa-utilisateur
 
Messages: 2287
Inscription: Mercredi 19 Novembre 2008, 15:35
Statut actuel: Post-bac


Retourner vers Asymptote

 


  • Articles en relation
    Réponses
    Vus
    Dernier message

Qui est en ligne

Utilisateurs parcourant ce forum: Aucun utilisateur enregistré et 2 invités