Construction d'une sphère

Tout ce qui concerne l'utilisation ou l'installation d'Asymptote.

Modérateur: gdm_asy

Règles du forum
Merci d'éviter le style SMS dans vos messages et de penser à utiliser la fonction Recherche avant de poster un message. Pour joindre des fichiers à vos messages, consulter ce sujet.
> Penser à utiliser les balises Code pour poster du code.

Construction d'une sphère

Messagepar rebouxo » Dimanche 12 Septembre 2010, 17:27

Il est temps de faire vivre la partie asymptote :D

J'ai dans l'idée de faire construire un modèle de la sphère aux élèves. J'ai donc pillé une activité et j'en suis à la réalisation de la sphère. Après avoir essayé un chouia pst-solides3d (décidément cette extension me paraît toujours aussi compliqué à faire fonctionner), je me suis tourné vers asymptote. Et là surprise, j'arrive à peu près à mes fins.

Pour que vous compreniez, il y a $6$ demi-cercles (qui jouent donc le rôle de méridiens, en rouge sur la figure) et $6$ disques de différents rayons. On emboîte les demi-disques dans les cercles dans lesquels on a pratiqué des encoches.

Voilà mon code asymptote :

Code: Tout sélectionner
import solids;

size(10cm,0);
currentprojection=orthographic((100,1, 1));
real r=6;// rayon de la sphere
real e=0.1;// épaisseur des cylindres
real h1 = 1,h2=3, h3=5 ;// hauteurs des cylindres.

revolution CercleV=cylinder((0, 0, 0),6, 0.1, X);

// Paralléle
real rayon=sqrt(r^2-h1^2) ;
real hauteur = h1-e/2 ;
revolution ParalleleN1=cylinder((0,0,hauteur),rayon,e,Z);
revolution ParalleleS1=cylinder((0,0,-hauteur),rayon,e,Z);
real rayon=sqrt(r^2-h2^2) ;
real hauteur = h2-e/2 ;
revolution ParalleleN2=cylinder((0,0,hauteur),rayon,e,Z);
revolution ParalleleS2=cylinder((0,0,-hauteur),rayon,e,Z);
real rayon=sqrt(r^2-h3^2) ;
real hauteur = h3-e/2 ;
revolution ParalleleN3=cylinder((0,0,hauteur),rayon,e,Z);
revolution ParalleleS3=cylinder((0,0,-hauteur),rayon,e,Z);
surface s = surface(sphere(O,6)) ;

// méridiens
revolution Meridien0 =cylinder((0,0,0),r,e,Y) ;
revolution Meridien60 =cylinder((0,0,0),r,e,(sqrt(3)/2,1/2,0)) ;
revolution Meridien120 =cylinder((0,0,0),r,e,(-sqrt(3)/2,1/2,0)) ;

draw(s,white) ;
draw(CercleV);
draw(surface(ParalleleS1),opacity(0.5)+lightblue);
draw(surface(ParalleleN1),opacity(0.5)+lightblue);
draw(surface(ParalleleS2),opacity(0.5)+lightblue);
draw(surface(ParalleleN2),opacity(0.5)+lightblue);
draw(surface(ParalleleS3),opacity(0.5)+lightblue);
draw(surface(ParalleleN3),opacity(0.5)+lightblue);
draw(surface(Meridien0),opacity(0.5)+red) ;
draw(surface(Meridien60),opacity(0.5)+red) ;
draw(surface(Meridien120),opacity(0.5)+red) ;


Mes problèmes :

  • les cylindres n'ont pas de bases ;
  • j'aimerais que tout soit opaques et donc faire disparaître la sphère, cela dit si le premier point...
  • il me semble que je pourrais alléger le code en faisant une fonction, pour mes pièces, mais là, la doc et les exemples ne sont pas mes amis.
  • Dernière question, pourquoi que cela ne fonctionne pas sur le site ?

Tout début de commencement de piste sera le bienvenu.
A line is a point that went for a walk. Paul Klee
Par solidarité, pas de MP
rebouxo
Modérateur
 
Messages: 6949
Inscription: Mercredi 15 Février 2006, 13:18
Localisation: le havre
Statut actuel: Actif et salarié | Enseignant

Publicité

Re: Construction d'une sphère

Messagepar MB » Dimanche 12 Septembre 2010, 17:58

A priori ça ne compile pas sur le forum à cause de la 3d (mais je n'ai pas encore bloqué les modules liés à la 3d). Le problème ne vient pas d'asymptote mais de la conversion en png.
Je pense que ça pourrait compiler en utilisant des options du genre :

Code: Tout sélectionner
settings.render = 0;
settings.prc = false;


et peut être aussi :

Code: Tout sélectionner
currentlight = nolight;


De toutes façons, sous linux, ton code fait planter evince et j'ai du mal à visualiser quelque chose de convenable avec acrobat reader.
Tu as vraiment besoin de pdf dynamique ?
MB (Pas d'aide en Message Privé)
Merci d'utiliser $\LaTeX$ (voir ici) et d'éviter le style SMS pour la lisibilité des messages.
MB
Administrateur
 
Messages: 6890
Inscription: Samedi 28 Mai 2005, 13:23
Localisation: Créteil
Statut actuel: Actif et salarié | Enseignant

Re: Construction d'une sphère

Messagepar chellier » Dimanche 12 Septembre 2010, 18:36

Je ne suis pas sûr d'avoir tout compris, mais est-ce que ce code fait ce que tu veux ?

Code: Tout sélectionner
import solids;

size(10cm,0);
currentprojection=orthographic((100,1, 1));
real r=6;// rayon de la sphere
real e=0.1;// épaisseur des cylindres
real h1 = 1,h2=3, h3=5 ;// hauteurs des cylindres.

revolution cylindre(triple c=O, real r, real h, triple axis=Z)
{
  triple C=c+r*perp(axis);
  axis=h*unit(axis);
  return revolution(c,c--C--C+axis--c+axis,axis);
}

revolution CercleV=cylindre((0, 0, 0),6, 0.1, X);

// Paralléle
real rayon=sqrt(r^2-h1^2) ;
real hauteur = h1-e/2 ;
revolution ParalleleN1=cylindre((0,0,hauteur),rayon,e,Z);
revolution ParalleleS1=cylindre((0,0,-hauteur),rayon,e,Z);
real rayon=sqrt(r^2-h2^2) ;
real hauteur = h2-e/2 ;
revolution ParalleleN2=cylindre((0,0,hauteur),rayon,e,Z);
revolution ParalleleS2=cylindre((0,0,-hauteur),rayon,e,Z);
real rayon=sqrt(r^2-h3^2) ;
real hauteur = h3-e/2 ;
revolution ParalleleN3=cylindre((0,0,hauteur),rayon,e,Z);
revolution ParalleleS3=cylindre((0,0,-hauteur),rayon,e,Z);
surface s = surface(sphere(O,6)) ;

// méridiens
revolution Meridien0 =cylindre((0,0,0),r,e,Y) ;
revolution Meridien60 =cylindre((0,0,0),r,e,(sqrt(3)/2,1/2,0)) ;
revolution Meridien120 =cylindre((0,0,0),r,e,(-sqrt(3)/2,1/2,0)) ;

//draw(s,white) ;
draw(CercleV);
draw(surface(ParalleleS1),opacity(0.5)+lightblue);
draw(surface(ParalleleN1),opacity(0.5)+lightblue);
draw(surface(ParalleleS2),opacity(0.5)+lightblue);
draw(surface(ParalleleN2),opacity(0.5)+lightblue);
draw(surface(ParalleleS3),opacity(0.5)+lightblue);
draw(surface(ParalleleN3),opacity(0.5)+lightblue);
draw(surface(Meridien0),opacity(0.5)+red) ;
draw(surface(Meridien60),opacity(0.5)+red) ;
draw(surface(Meridien120),opacity(0.5)+red) ;


sphere.png
sphère


Christophe
chellier
Modérateur
 
Messages: 355
Inscription: Samedi 25 Juillet 2009, 11:25
Localisation: Le Creusot
Statut actuel: Actif et salarié | Enseignant

Re: Construction d'une sphère

Messagepar rebouxo » Dimanche 12 Septembre 2010, 19:08

@chellier : super exactement ce que je veux. La figure est nickel. Bon par contre le code est le même que le mien. Je vois que tu as commencé par définir quelquechose, mais tu t'en sers pas ? Ou bien j'ai pas compris.
@ MB : non je ne fais pas du dynamique, mais du statique de chez statique. J'ai un -render=0 dans mon makefile, peut-être que cela réglera tes problèmes ?

Olivier
A line is a point that went for a walk. Paul Klee
Par solidarité, pas de MP
rebouxo
Modérateur
 
Messages: 6949
Inscription: Mercredi 15 Février 2006, 13:18
Localisation: le havre
Statut actuel: Actif et salarié | Enseignant

Re: Construction d'une sphère

Messagepar chellier » Dimanche 12 Septembre 2010, 20:45

rebouxo a écrit:@chellier : super exactement ce que je veux. La figure est nickel. Bon par contre le code est le même que le mien. Je vois que tu as commencé par définir quelquechose, mais tu t'en sers pas ? Ou bien j'ai pas compris.
Olivier


Euh, tu n'as pas compris :wink:

J'ai créé un nouveau type "cylindre" pour rajouter les bases. Tu dois voir que j'ai changé tous les "cylinder" de ton code en "cylindre".

J'ai aussi créé une fonction pour le tracé des parallèles dans le code ci-dessous. Mais on doit quand même pouvoir faire mieux :

Code: Tout sélectionner
import solids;

size(10cm,0);
currentprojection=orthographic((100,25,25));

real r=6;// rayon de la sphere
real e=0.1;// épaisseur des cylindres
real h1 = 1,h2=3, h3=5 ;// hauteurs des cylindres.

revolution cylindre(triple c=O, real r, real h, triple axis=Z)
{
  triple C=c+r*perp(axis);
  axis=h*unit(axis);
  return revolution(c,c--C--C+axis--c+axis,axis);
}

void paralleles(real rayon, real hauteur, real epaisseur=e, pen p=opacity(0.5)+lightblue){
   revolution ParalleleN=cylindre((0,0,hauteur),rayon,epaisseur,Z);
   revolution ParalleleS=cylindre((0,0,-hauteur),rayon,epaisseur,Z);
   draw(surface(ParalleleS),p);
   draw(surface(ParalleleN),p);
}

// Parallèle
paralleles(rayon=sqrt(r^2-h1^2),hauteur=h1-e/2);
paralleles(rayon=sqrt(r^2-h2^2),hauteur=h2-e/2);
paralleles(rayon=sqrt(r^2-h3^2),hauteur=h3-e/2);

// méridiens
revolution Meridien0 =cylindre((0,0,0),r,e,Y) ;
revolution Meridien60 =cylindre((0,0,0),r,e,(sqrt(3)/2,1/2,0)) ;
revolution Meridien120 =cylindre((0,0,0),r,e,(-sqrt(3)/2,1/2,0)) ;

draw(surface(Meridien0),opacity(0.5)+red) ;
draw(surface(Meridien60),opacity(0.5)+red) ;
draw(surface(Meridien120),opacity(0.5)+red) ;


Christophe
chellier
Modérateur
 
Messages: 355
Inscription: Samedi 25 Juillet 2009, 11:25
Localisation: Le Creusot
Statut actuel: Actif et salarié | Enseignant

Re: Construction d'une sphère

Messagepar MB » Dimanche 12 Septembre 2010, 21:09

rebouxo a écrit:@ MB : non je ne fais pas du dynamique, mais du statique de chez statique. J'ai un -render=0 dans mon makefile, peut-être que cela réglera tes problèmes ?


Ok, ça correspond à :

Code: Tout sélectionner
settings.render = 0;


Donc tu passais cette option au niveau de la commande et non dans le fichier (je préfère le faire dans le fichier). Par contre, pour l'utilisation d'asymptote sur le site, il serait peut être judicieux d'ajouter cette options par défaut à la commande de compilation. :idea:
MB (Pas d'aide en Message Privé)
Merci d'utiliser $\LaTeX$ (voir ici) et d'éviter le style SMS pour la lisibilité des messages.
MB
Administrateur
 
Messages: 6890
Inscription: Samedi 28 Mai 2005, 13:23
Localisation: Créteil
Statut actuel: Actif et salarié | Enseignant

Re: Construction d'une sphère

Messagepar rebouxo » Dimanche 12 Septembre 2010, 22:00

@MB : oui, je fais cela dans le makefile. Dans mon source, il n'y a pas d'information sur la compilation. C'est comme cela, je n'en veux pas.
@chellier : j'avions point vu. Mais la lecture de ton code ne m'éclaire absolument pas.

Code: Tout sélectionner
revolution cylindre(triple c=O, real r, real h, triple axis=Z)
{
  triple C=c+r*perp(axis);
  axis=h*unit(axis);
  return revolution(c,c--C--C+axis--c+axis,axis);
}


Bon donc tu crées un nouvel objet qui prend quatre arguments. Pourquoi le premier et le dernier sont fixés ou bien ce sont des arguments par défaut ?
C : c'est un point, on le défini à partir de c, mais que fais donc r*perp(axis) ?
Ensuite tu raccourcis axis.
La dernière ligne tu crées le cylindre complet : tu part de c et tu vas à C, mais ensuite tu repars vers C ???? :crybaby:

Merci pour tes renseignements.

Bon, alors j'ai une ancienneté d'asymptote (1.84) et ta belle image devient chez moi un infâme salimongis. Les différents éléments semblent être empilés les uns sur les autres. J'essaye de désinstaller (c'était pas une installation par les paquets) et j'installe la 1.91 depuis les paquets mandriva
Olivier
A line is a point that went for a walk. Paul Klee
Par solidarité, pas de MP
rebouxo
Modérateur
 
Messages: 6949
Inscription: Mercredi 15 Février 2006, 13:18
Localisation: le havre
Statut actuel: Actif et salarié | Enseignant

Re: Construction d'une sphère

Messagepar MB » Dimanche 12 Septembre 2010, 22:04

rebouxo a écrit:Dans mon source, il n'y a pas d'information sur la compilation. C'est comme cela, je n'en veux pas.


Je ne vois pas vraiment le problème, en plus c'est plus simple lorsque tu veux transmettre ton code (ici par exemple).
MB (Pas d'aide en Message Privé)
Merci d'utiliser $\LaTeX$ (voir ici) et d'éviter le style SMS pour la lisibilité des messages.
MB
Administrateur
 
Messages: 6890
Inscription: Samedi 28 Mai 2005, 13:23
Localisation: Créteil
Statut actuel: Actif et salarié | Enseignant

Re: Construction d'une sphère

Messagepar rebouxo » Dimanche 12 Septembre 2010, 22:19

MB a écrit:
rebouxo a écrit:Dans mon source, il n'y a pas d'information sur la compilation. C'est comme cela, je n'en veux pas.


Je ne vois pas vraiment le problème, en plus c'est plus simple lorsque tu veux transmettre ton code (ici par exemple).


J'aime bien séparer les choses, c'est tout. Mais en fait je ne me suis jamais posé la question plus que cela.
Bon, ben même avec la version 1.91 ça marche pas. Donc il va falloir encore bricoler.

EDIT : pareil avec la version 2.04.
Voilà l'horreur :

sphere.png
sphere.png (6.65 Kio) Vu 1865 fois


Olivier
A line is a point that went for a walk. Paul Klee
Par solidarité, pas de MP
rebouxo
Modérateur
 
Messages: 6949
Inscription: Mercredi 15 Février 2006, 13:18
Localisation: le havre
Statut actuel: Actif et salarié | Enseignant

Re: Construction d'une sphère

Messagepar chellier » Dimanche 12 Septembre 2010, 22:36

rebouxo a écrit:
Code: Tout sélectionner
revolution cylindre(triple c=O, real r, real h, triple axis=Z)
{
  triple C=c+r*perp(axis);
  axis=h*unit(axis);
  return revolution(c,c--C--C+axis--c+axis,axis);
}


Bon donc tu crées un nouvel objet qui prend quatre arguments. Pourquoi le premier et le dernier sont fixés ou bien ce sont des arguments par défaut ?
C : c'est un point, on le défini à partir de c, mais que fais donc r*perp(axis) ?
Ensuite tu raccourcis axis.
La dernière ligne tu crées le cylindre complet : tu part de c et tu vas à C, mais ensuite tu repars vers C ???? :crybaby:


Le premier et le dernier argument sont des arguments par défaut. Si on ne les redéfinit pas, ils auront ces valeurs.
C est un point situé à une distance r de c, perpendiculairement à Z.
Je joins 4 points : c, C, C+axis et c+axis. Une figure pour mieux suivre :

Code: Tout sélectionner
import solids;
size(5cm);
settings.render=0;
settings.prc=false;
real h=.75;  //hauteur
real r=.5;  //rayon
triple c=O;
triple C=c+r*perp(Z);
xaxis3("$X$",0,1,Arrow3);
yaxis3("$Y$",0,1,Arrow3);
zaxis3("$Z$",0,1,Arrow3);

draw(c--C,blue);
draw(C--C+h*Z,magenta);
draw(C+h*Z--c+h*Z,green);

dot(C,2bp+red);


generatrice.png
generatrice.png (30.75 Kio) Vu 1865 fois


Ensuite, je fais tourner le tout :D
Christophe

Edit : la figure ne passe pas sur le forum :(
chellier
Modérateur
 
Messages: 355
Inscription: Samedi 25 Juillet 2009, 11:25
Localisation: Le Creusot
Statut actuel: Actif et salarié | Enseignant

Re: Construction d'une sphère

Messagepar rebouxo » Dimanche 12 Septembre 2010, 22:42

OK. Merci pour ces renseignements. Bon aujourd'hui on va dire qu'il est l'heure d'aller se coucher. Mais j'aimerais bien comprendre maintenant pourquoi j'ai une figure toute moche.

Olivier
A line is a point that went for a walk. Paul Klee
Par solidarité, pas de MP
rebouxo
Modérateur
 
Messages: 6949
Inscription: Mercredi 15 Février 2006, 13:18
Localisation: le havre
Statut actuel: Actif et salarié | Enseignant

Re: Construction d'une sphère

Messagepar chellier » Dimanche 12 Septembre 2010, 22:44

rebouxo a écrit:Voilà l'horreur :


J'obtiens la même chose si je compile avec

Code: Tout sélectionner
settings.render=0; // ou 4, 8, etc
settings.prc=false;


Pour avoir une "belle figure", je compile le code comme donné, et j'ouvre le pdf avec acrobat reader. Ensuite, on peut faire tourner la figure et le rendu est très bon.
Pour les autres lecteurs pdf, il faut peut-être jouer avec les lumières... :?

Christophe
chellier
Modérateur
 
Messages: 355
Inscription: Samedi 25 Juillet 2009, 11:25
Localisation: Le Creusot
Statut actuel: Actif et salarié | Enseignant

Re: Construction d'une sphère

Messagepar MB » Lundi 13 Septembre 2010, 00:22

chellier a écrit:la figure ne passe pas sur le forum :(


J'ai regardé de plus près et le problème vient du fait qu'il manque le paquet latex url.
Pour l'instant, je n'ai pas pu l'installer en raison de ce problème. Je regarde ça dès que je peux : soit j'arrive à installer le paquet en restant sur une version 2009, soit il faudra mettre à jour texlive en version 2010 sur le serveur.
MB (Pas d'aide en Message Privé)
Merci d'utiliser $\LaTeX$ (voir ici) et d'éviter le style SMS pour la lisibilité des messages.
MB
Administrateur
 
Messages: 6890
Inscription: Samedi 28 Mai 2005, 13:23
Localisation: Créteil
Statut actuel: Actif et salarié | Enseignant

Re: Construction d'une sphère

Messagepar rebouxo » Lundi 13 Septembre 2010, 10:56

Il va falloir me dire pourquoi la méthode de compilation joue sur la représentation de la figure. :annoyed: :pullhair:
Il est très clair qu'avec la méthode que j'utilise les objets ne sont que posé sur un plan en les empilant. J'appelle pas cela de la 3D.

Olivier
A line is a point that went for a walk. Paul Klee
Par solidarité, pas de MP
rebouxo
Modérateur
 
Messages: 6949
Inscription: Mercredi 15 Février 2006, 13:18
Localisation: le havre
Statut actuel: Actif et salarié | Enseignant

Re: Construction d'une sphère

Messagepar rebouxo » Lundi 13 Septembre 2010, 14:11

Bon ben avec la bonne méthode de compilation c'est tout très bô (en ps ou en pdf, par contre la figure reste fixe dans le pdf, faut-il impérativement passer par pdfLatex ?). Je vais encore bidouiller la place de la lumière et je vais mettre dans mon environnement asy la méthode de compilation. Quelqu'un a-t-il déjà essayer plusieurs méthodes de compilation dans un même document tex ?
Si je compile avec -render = 0 c'est que j'avais des problèmes avec des figures dans l'espace (je ne fais que de l'espace avec asymptote), en particuliers des problèmes de couleurs sur des surfaces. Or je voudrais bien éviter la technique de l'image externe, si c'était possible.

Olivier
A line is a point that went for a walk. Paul Klee
Par solidarité, pas de MP
rebouxo
Modérateur
 
Messages: 6949
Inscription: Mercredi 15 Février 2006, 13:18
Localisation: le havre
Statut actuel: Actif et salarié | Enseignant

Re: Construction d'une sphère

Messagepar chellier » Lundi 13 Septembre 2010, 15:53

rebouxo a écrit:Bon ben avec la bonne méthode de compilation c'est tout très bô (en ps ou en pdf, par contre la figure reste fixe dans le pdf, faut-il impérativement passer par pdfLatex ?)

Quelles sont tes options de compilation (latex et asymptote) ?

Christophe
chellier
Modérateur
 
Messages: 355
Inscription: Samedi 25 Juillet 2009, 11:25
Localisation: Le Creusot
Statut actuel: Actif et salarié | Enseignant

Re: Construction d'une sphère

Messagepar MB » Lundi 13 Septembre 2010, 17:34

C'est bon, ton image compile maintenant Christophe (il fallait installer les paquets latex url, movie15, ms et fp).

124922ae2264eaca68bc07ed0595afc5.png

Code: Tout sélectionner
import solids;
size(5cm);
settings.render=0;
settings.prc=false;
real h=.75; //hauteur
real r=.5; //rayon
triple c=O;
triple C=c+r*perp(Z);
xaxis3("$X$",0,1,Arrow3);
yaxis3("$Y$",0,1,Arrow3);
zaxis3("$Z$",0,1,Arrow3);

draw(c--C,blue);
draw(C--C+h*Z,magenta);
draw(C+h*Z--c+h*Z,green);

dot(C,2bp+red);
MB (Pas d'aide en Message Privé)
Merci d'utiliser $\LaTeX$ (voir ici) et d'éviter le style SMS pour la lisibilité des messages.
MB
Administrateur
 
Messages: 6890
Inscription: Samedi 28 Mai 2005, 13:23
Localisation: Créteil
Statut actuel: Actif et salarié | Enseignant

Re: Construction d'une sphère

Messagepar chellier » Lundi 13 Septembre 2010, 19:39

MB a écrit:C'est bon, ton image compile maintenant Christophe (il fallait installer les paquets latex url, movie15, ms et fp).

Super :D

Christophe
chellier
Modérateur
 
Messages: 355
Inscription: Samedi 25 Juillet 2009, 11:25
Localisation: Le Creusot
Statut actuel: Actif et salarié | Enseignant

Re: Construction d'une sphère

Messagepar rebouxo » Lundi 13 Septembre 2010, 22:19

chellier a écrit:Quelles sont tes options de compilation (latex et asymptote) ?


Je compile via latex+dvips+ps2pdf (pstricks fan). Pour asymptote la seule que j'ai est le -render=0.

Olivier
A line is a point that went for a walk. Paul Klee
Par solidarité, pas de MP
rebouxo
Modérateur
 
Messages: 6949
Inscription: Mercredi 15 Février 2006, 13:18
Localisation: le havre
Statut actuel: Actif et salarié | Enseignant

Re: Construction d'une sphère

Messagepar chellier » Mardi 14 Septembre 2010, 11:50

Il faut impérativement ouvrir le pdf avec acrobat reader pour avoir une figure que l'on peut manipuler (c'est le format prc d'Adobe). Normalement avec tes options de compilation, ça devrait être bon.
Par contre, ce que je ne comprends pas, c'est que tu arrives à avoir une "belle" figure directement. Moi je ne l'obtiens qu'une fois la figure activée dans acrobat reader, sinon j'ai les différents éléments empilés... Ça me dépasse :( tu as rajouté quelque chose au code ?

Christophe
chellier
Modérateur
 
Messages: 355
Inscription: Samedi 25 Juillet 2009, 11:25
Localisation: Le Creusot
Statut actuel: Actif et salarié | Enseignant

Suivante

Retourner vers Asymptote

 


  • Articles en relation
    Réponses
    Vus
    Dernier message

Qui est en ligne

Utilisateurs parcourant ce forum: Aucun utilisateur enregistré et 1 invité