Angles droits et 3D

Tout ce qui concerne l'utilisation ou l'installation d'Asymptote.

Modérateur: gdm_asy

Règles du forum
Merci d'éviter le style SMS dans vos messages et de penser à utiliser la fonction Recherche avant de poster un message. Pour joindre des fichiers à vos messages, consulter ce sujet.
> Penser à utiliser les balises Code pour poster du code.

Angles droits et 3D

Messagepar guiguiche » Samedi 24 Décembre 2011, 16:42

Je cherche à tracer des angles droits en 3D (vecteurs e1 et e2 ainsi que pour le projeté orthogonal) :

2d66bd4bbc7f3a6c7a9bcfa412c0a07c.png

Code: Tout sélectionner
import graph3 ;

// Les paramètres de l'image à générer
size(8cm); // la dimension de l'image
currentprojection=orthographic((15,10,5),up=Z); // le type de représentation
//currentlight=light(5,2,0); // la luminosité ??
limits(O,3X+3Y+Z); // la fenêtre de vue

//----------------------------------------------------

// Les paramètres mathématiques à modifier
pair mini=(-1,-1) ; // coordonnées minimales dans le plan de départ
pair maxi=(3,3) ; // coordonnées maximales dans le plan de départ

//----------------------------------------------------

// Définition des éléments graphiques à représenter
surface p0=surface(plane((maxi.x-mini.x,0,0),(0,maxi.y-mini.y,0),(mini.x,mini.y,0))) ; // le plan de projection
triple u=(1.3,1.7,2.4) ; // le vecteur que l'on veut projeter
triple pu=(u.x,u.y,0) ; // le projeté orthogonal de u sur le plan
triple xu=(u.x,0,0) ; // la première composante de u
triple yu=(0,u.y,0) ; // la deuxième composante de u
triple e1=(1,0,0) ; // le vecteur unitaire e1
triple e2=(0,1,0) ; // le vecteur unitaire e2
triple pointO=(0,0,0) ; // l'origine du repère

//----------------------------------------------------

// Représentation graphique
draw(p0,paleblue+opacity(.5)); // le plan p0 de projection
draw("$\vec{u}$",pointO--u,black,Arrow3()) ; // le vecteur u dans l'espace
draw("$p_F(\vec{u})$",pointO--pu,red,Arrow3()) ; // le vecteur pu dans le plan p0
draw(pointO--xu,blue,Arrow3()) ; // le vecteur xu dans le plan p0
draw(pointO--yu,blue,Arrow3()) ; // le vecteur yu dans le plan p0
draw("$\vec{e}_1$",pointO--e1,green,Arrow3()) ; // le vecteur e1 dans le plan p0
draw("$\vec{e}_2$",pointO--e2,green,Arrow3()) ; // le vecteur e2 dans le plan p0
draw(xu--pu,blue+dashed) ; // la coordonnée x de u
draw(yu--pu,blue+dashed) ; // la coordonnée y de u
draw(pu--u,red+dashed) ; // on relie u et son projeté pu


J'ai bien trouvé ce vieux message mais peut-être asymptote a-t-il évolué de ce côté-ci en 4 ans ? Et je n'ai rien trouvé sur la galerie de GMaths.

HS de la question principale : comment noter "F" le plan de projection car je ne comprends pas pourquoi le "$F$" ou le "F" est refusé en premier argument ?
Pas d'aide par MP : les questions sont publiques, les réponses aussi.
Tu as apprécié l'aide qui t'a été fournie ? Alors n'hésite pas à rendre la pareille à quelqu'un d'autre.
Un peu d'autopromotion.
guiguiche
Modérateur
 
Messages: 8073
Inscription: Vendredi 06 Janvier 2006, 15:32
Localisation: Le Mans
Statut actuel: Actif et salarié | Enseignant

Publicité

Re: angles droits et 3D

Messagepar GMaths » Samedi 24 Décembre 2011, 17:30

Passage en coup de vent...

Il n'y a pas de fonction prévue pour un angle droit... donc à moins d'en écrire une... il faut bricoler.
Un bricolage rapide... pour dépanner :
Code: Tout sélectionner
real a=.3;
draw(pu+a*Z--(pu+a*(Z-dir(pu))--(pu-a*dir(pu))));

Pas le temps de faire mieux.

On peut labelliser un triple ou un path3 mais pas une surface effectivement... car il y aurait le problème du positionnement par rapport à la surface, qui a dû être estimé difficile à gérer.
Il faut utiliser la fonction label("...",untripledelasurface,directiondulabel).
GMaths
Exa-utilisateur
 
Messages: 2031
Inscription: Lundi 01 Octobre 2007, 09:20
Statut actuel: Actif et salarié | Enseignant

Re: angles droits et 3D

Messagepar guiguiche » Samedi 24 Décembre 2011, 18:11

Merci, je vais me contenter de ta solution pour le moment.

cc02ded5805fd20d8f96f2f399029ce8.png

Code: Tout sélectionner
import graph3 ;

// Les paramètres de l'image à générer
size(10cm); // la dimension de l'image
currentprojection=orthographic((15,10,5),up=Z); // le type de représentation
//currentlight=light(5,2,0); // la luminosité ??
limits(O,3X+3Y+Z); // la fenêtre de vue

//----------------------------------------------------

// Les paramètres mathématiques à modifier
pair mini=(-1,-1) ; // coordonnées minimales dans le plan de départ
pair maxi=(3,3) ; // coordonnées maximales dans le plan de départ
real a=.2 ; // pour dessiner les angles droits

//----------------------------------------------------

// Définition des éléments graphiques à représenter
surface F=surface(plane((maxi.x-mini.x,0,0),(0,maxi.y-mini.y,0),(mini.x,mini.y,0))) ; // le plan de projection
triple u=(1.3,1.7,2.4) ; // le vecteur que l'on veut projeter
triple pu=(u.x,u.y,0) ; // le projeté orthogonal de u sur le plan
triple xu=(u.x,0,0) ; // la première composante de u
triple yu=(0,u.y,0) ; // la deuxième composante de u

//----------------------------------------------------

// Représentation graphique
draw(F,paleblue+opacity(.5)); // le plan F de projection
draw("$\vec{u}$",O--u,black,Arrow3()) ; // le vecteur u dans l'espace
draw("$p_F(\vec{u})$",O--pu,red,Arrow3()) ; // le vecteur pu dans le plan F
draw(O--xu,blue,Arrow3()) ; // le vecteur xu dans le plan F
draw(O--yu,blue,Arrow3()) ; // le vecteur yu dans le plan F
draw("$\vec{e}_1$",O--X,green,Arrow3()) ; // le vecteur e1 dans le plan F
draw("$\vec{e}_2$",O--Y,green,Arrow3()) ; // le vecteur e2 dans le plan F
draw(xu--pu,blue+dashed) ; // on relie xu et pu
draw(yu--pu,blue+dashed) ; // on relie yu et pu
draw(pu--u,red+dashed) ; // on relie u et son projeté pu
draw(pu+a*Z--(pu+a*(Z-dir(pu))--(pu-a*dir(pu))),red) ; // on trace l'angle droit de projection
draw(a*X--a*X+a*Y--a*Y,green) ; // on trace l'angle droit de projection
Pas d'aide par MP : les questions sont publiques, les réponses aussi.
Tu as apprécié l'aide qui t'a été fournie ? Alors n'hésite pas à rendre la pareille à quelqu'un d'autre.
Un peu d'autopromotion.
guiguiche
Modérateur
 
Messages: 8073
Inscription: Vendredi 06 Janvier 2006, 15:32
Localisation: Le Mans
Statut actuel: Actif et salarié | Enseignant

Re: angles droits et 3D

Messagepar guiguiche » Samedi 24 Décembre 2011, 18:22

Pourquoi ça ne passe pas : draw(Label("$F$",(1.8,-0.8,0),(0,0,1)),F,paleblue+opacity(.5)); ?
Pas d'aide par MP : les questions sont publiques, les réponses aussi.
Tu as apprécié l'aide qui t'a été fournie ? Alors n'hésite pas à rendre la pareille à quelqu'un d'autre.
Un peu d'autopromotion.
guiguiche
Modérateur
 
Messages: 8073
Inscription: Vendredi 06 Janvier 2006, 15:32
Localisation: Le Mans
Statut actuel: Actif et salarié | Enseignant

Re: angles droits et 3D

Messagepar GMaths » Samedi 24 Décembre 2011, 19:17

guiguiche a écrit:Pourquoi ça ne passe pas : draw(Label("$F$",(1.8,-0.8,0),(0,0,1)),F,paleblue+opacity(.5)); ?

Il y a une commande label (avec un l minuscule)... qui ne nécessite pas draw !
GMaths
Exa-utilisateur
 
Messages: 2031
Inscription: Lundi 01 Octobre 2007, 09:20
Statut actuel: Actif et salarié | Enseignant

Re: angles droits et 3D

Messagepar GMaths » Samedi 24 Décembre 2011, 19:24

GMaths a écrit:Il y a une commande label (avec un l minuscule)... qui ne nécessite pas draw !

Chercher "void" - "label" via le lien index de ma signature.
GMaths
Exa-utilisateur
 
Messages: 2031
Inscription: Lundi 01 Octobre 2007, 09:20
Statut actuel: Actif et salarié | Enseignant

Re: angles droits et 3D

Messagepar GMaths » Dimanche 25 Décembre 2011, 02:53

Une fonction angledroit... qui devra probablement être améliorée :

Image


Intéressant à remarquer pour ceux qui débutent avec Asymptote, l'utilisation des fonctions :
  • planeproject :
    1. // Transform3 that projects in direction dir onto plane with normal n through point O.
      Code: Tout sélectionner
      transform3 planeproject(triple n, triple O=O, triple dir=n)
    2. // Transform3 that projects in direction dir onto plane defined by p.
      Code: Tout sélectionner
      transform3 planeproject(path3 p, triple dir=O)
  • cross : pour le produit vectoriel
  • rotate :
    1. // A transformation representing rotation by an angle in degrees about an axis v through the origin (in the right-handed direction).
      Code: Tout sélectionner
      transform3 rotate(real angle, triple v)
    2. // A transformation representing rotation by an angle in degrees about the line u--v (in the right-handed direction).
      Code: Tout sélectionner
      transform3 rotate(real angle, triple u, triple v)
  • interp :
    The function
    Code: Tout sélectionner
    T interp(T a, T b, real t)
    returns
    Code: Tout sélectionner
    (1-t)*a+t*b
    for nonintegral built-in arithmetic types T.
    If a and b are pens, they are first promoted to the same color space.
GMaths
Exa-utilisateur
 
Messages: 2031
Inscription: Lundi 01 Octobre 2007, 09:20
Statut actuel: Actif et salarié | Enseignant

Re: angles droits et 3D

Messagepar guiguiche » Lundi 26 Décembre 2011, 15:51

Merci

ced182a059b9c39fdbb06fb3989777ea.png

Code: Tout sélectionner
import graph3 ;


// Les paramètres de l'image à générer
size(10cm); // la dimension de l'image
currentprojection=orthographic((15,10,5),up=Z); // le type de représentation
//currentlight=light(5,2,0); // la luminosité ??
limits(O,3X+3Y+Z); // la fenêtre de vue


// Définition de la procédure de tracé d'un angle droit
void angledroit(picture pic=currentpicture,
triple pO, triple pI, triple pJ, real size=.5, pen p=black,
projection P=currentprojection){
triple imI=pO+size*unit(pI-pO),
imJ=pO+size*unit(pJ-pO),
imK=imI+imJ-pO;
draw(imI--imK--imJ,p);
}


// Les paramètres mathématiques à modifier
pair mini=(-1,-1) ; // coordonnées minimales dans le plan de départ
pair maxi=(3,3) ; // coordonnées maximales dans le plan de départ
real a=0.2 ; // coefficient pour tracé des angles droits

// Définition des éléments graphiques à représenter
surface F=surface(plane((maxi.x-mini.x,0,0),(0,maxi.y-mini.y,0),(mini.x,mini.y,0))) ; // le plan de projection
triple u=(1.3,1.7,2.4) ; // le vecteur que l'on veut projeter
triple pu=(u.x,u.y,0) ; // le projeté orthogonal de u sur le plan
triple xu=(u.x,0,0) ; // la première composante de u
triple yu=(0,u.y,0) ; // la deuxième composante de u


// Représentation graphique
draw(F,paleblue+opacity(.5)); // le plan F de projection
label("$F$",(2.8,-0.6,0),(0,0,1)) ; // placement du label F
draw("$\vec{u}$",O--u,black,Arrow3()) ; // le vecteur u dans l'espace
draw("$p_F(\vec{u})$",O--pu,red,Arrow3()) ; // le vecteur pu dans le plan F
draw(O--xu,blue,Arrow3()) ; // le vecteur xu dans le plan F
draw(O--yu,blue,Arrow3()) ; // le vecteur yu dans le plan F
draw("$\vec{e}_1$",O--X,green,Arrow3()) ; // le vecteur e1 dans le plan F
draw("$\vec{e}_2$",O--Y,green,Arrow3()) ; // le vecteur e2 dans le plan F
draw(xu--pu,blue+dashed) ; // on relie xu et pu
draw(yu--pu,blue+dashed) ; // on relie yu et pu
draw(pu--u,red+dashed) ; // on relie u et son projeté pu
angledroit(pu,O,u,a,red) ; // on trace l'angle droit de projection
angledroit(O,X,Y,a,green) ; // on trace l'angle droit des vecteurs de la base


HS : je n'ai pas la coloration syntaxique dans notepad++ malgré le téléchargement du fichier mentionné ici (il n'y a aucune couleur par défaut et si je modifie quelques couleurs, rien concernant les mots clé, éventuellement une coloration de quelques nombres et même pas tous). D'ailleurs, je pense que ce message ainsi que des précédents devraient figurer en post-it sur le forum).
Pas d'aide par MP : les questions sont publiques, les réponses aussi.
Tu as apprécié l'aide qui t'a été fournie ? Alors n'hésite pas à rendre la pareille à quelqu'un d'autre.
Un peu d'autopromotion.
guiguiche
Modérateur
 
Messages: 8073
Inscription: Vendredi 06 Janvier 2006, 15:32
Localisation: Le Mans
Statut actuel: Actif et salarié | Enseignant

Re: angles droits et 3D

Messagepar GMaths » Lundi 26 Décembre 2011, 17:01

guiguiche a écrit:HS : je n'ai pas la coloration syntaxique dans notepad++ malgré le téléchargement du fichier mentionné ici (il n'y a aucune couleur par défaut et si je modifie quelques couleurs, rien concernant les mots clé, éventuellement une coloration de quelques nombres et même pas tous).

Tu as fait ce que suggère l'image : l'importation du fichier ? Tu as fermé et relancé Notepad++ ?
Attention à la remarque : "importation d'un fichier" ou "modification des couleurs au niveau du panneau de l'utilisateur"... il fallait choisir et ne pas mêler les deux méthodes... il y a quelques temps de cela. Je n'ai pas re-testé.

guiguiche a écrit:D'ailleurs, je pense que ce message ainsi que des précédents devraient figurer en post-it sur le forum).

Je vais refaire un tutoriel très imagé sur notepad++ cette semaine qui... atterrira vraisemblablement .
GMaths
Exa-utilisateur
 
Messages: 2031
Inscription: Lundi 01 Octobre 2007, 09:20
Statut actuel: Actif et salarié | Enseignant

Re: angles droits et 3D

Messagepar guiguiche » Lundi 26 Décembre 2011, 17:37

Oui, j'ai fermé et relancé, je ne vois aucune différence.
J'ai modifié dans le profil créé avec l'import puisque cela ne donnait rien. Mais je vais recommencer.

Ma dernière création : illustration du procédé d'orthonormalisation de Schmidt

79dc8f032500f26c46b69140721a33eb.png

Code: Tout sélectionner
import graph3 ;

size(10cm); // la dimension de l'image
currentprojection=orthographic((10,5,15),up=Z); // le type de représentation
//currentlight=light(5,2,0); // la luminosité ??
limits(O,3X+3Y+3Z); // la fenêtre de vue

void angledroit(picture pic=currentpicture,
triple pO, triple pI, triple pJ, real size=.5, pen p=black,
projection P=currentprojection){
triple imI=pO+size*unit(pI-pO),
imJ=pO+size*unit(pJ-pO),
imK=imI+imJ-pO;
draw(imI--imK--imJ,p);
}


real prodscal(triple u, triple v) { return u.x*v.x+u.y*v.y+u.z*v.z ; }
real norme(triple u) { return sqrt(prodscal(u,u)) ; }

real a=0.2 ; // coefficient pour tracé des angles droits

triple x1=(2.5,1.6,0) ; // un vecteur x1
triple x2=(1.7,-0.5,0) ; // un vecteur x2 non colinéaire à x1
triple x3=(1.3,1.7,2.4) ; // un vecteur x3 non coplanaire à Vect(x1,x2)
triple e1=1/norme(x1)*x1 ;
triple y2=x2-prodscal(x2,e1)*e1 ;
triple e2=1/norme(y2)*y2 ;
triple y3=x3-prodscal(x3,e1)*e1-prodscal(x3,e2)*e2 ;
triple e3=1/norme(y3)*y3 ;

draw("$\vec{x}_1$",O--x1,blue,Arrow3()) ; // le vecteur x1
draw("$\vec{x}_2$",O--x2,blue,Arrow3()) ; // le vecteur x2
draw("$\vec{x}_3$",O--x3,blue,Arrow3()) ; // le vecteur x3
draw("$\vec{y}_2$",O--y2,green,Arrow3()) ; // le vecteur y2
draw(x2--y2,green+dashed) ; // on relie x2 et y2
angledroit(y2,O,x2,a,green) ; // on trace l'angle droit en y2
draw("$\vec{y}_3$",O--y3,green,Arrow3()) ; // le vecteur y3
draw(x3--y3,green+dashed) ; // on relie x3 et y3
angledroit(y3,O,x3,a,green) ; // on trace l'angle droit en y3
draw("$\vec{e}_1$",O--e1,red,Arrow3()) ; // le vecteur e1
draw("$\vec{e}_2$",O--e2,red,Arrow3()) ; // le vecteur e2
draw("$\vec{e}_3$",O--e3,red,Arrow3()) ; // le vecteur e3
angledroit(O,e1,e2,a,red) ;
angledroit(O,e1,e3,a,red) ;
angledroit(O,e2,e3,a,red) ;
Pas d'aide par MP : les questions sont publiques, les réponses aussi.
Tu as apprécié l'aide qui t'a été fournie ? Alors n'hésite pas à rendre la pareille à quelqu'un d'autre.
Un peu d'autopromotion.
guiguiche
Modérateur
 
Messages: 8073
Inscription: Vendredi 06 Janvier 2006, 15:32
Localisation: Le Mans
Statut actuel: Actif et salarié | Enseignant

Re: angles droits et 3D

Messagepar GMaths » Jeudi 29 Décembre 2011, 14:32

GMaths a écrit:Je vais refaire un tutoriel très imagé sur notepad++ cette semaine qui... atterrira vraisemblablement .


En voilà un premier jet.

J'ai plusieurs idées d'améliorations... mais je retourne à mes corrections de copies d'abord.
GMaths
Exa-utilisateur
 
Messages: 2031
Inscription: Lundi 01 Octobre 2007, 09:20
Statut actuel: Actif et salarié | Enseignant

Re: angles droits et 3D

Messagepar guiguiche » Jeudi 29 Décembre 2011, 16:12

Je pense que c'était l'inversion import/export qui m'a planté. Merci pour le tuto.
Pas d'aide par MP : les questions sont publiques, les réponses aussi.
Tu as apprécié l'aide qui t'a été fournie ? Alors n'hésite pas à rendre la pareille à quelqu'un d'autre.
Un peu d'autopromotion.
guiguiche
Modérateur
 
Messages: 8073
Inscription: Vendredi 06 Janvier 2006, 15:32
Localisation: Le Mans
Statut actuel: Actif et salarié | Enseignant

Re: angles droits et 3D

Messagepar GMaths » Vendredi 30 Décembre 2011, 13:37

guiguiche a écrit:Merci pour le tuto.


J'en ai ajouté un nouveau sur l'utilisation de texworks avec Asymptote.
GMaths
Exa-utilisateur
 
Messages: 2031
Inscription: Lundi 01 Octobre 2007, 09:20
Statut actuel: Actif et salarié | Enseignant

Re: angles droits et 3D

Messagepar texmaker » Jeudi 12 Janvier 2012, 18:22


Et avec Texmaker (3.2.2) :
- coloration syntaxique par défaut sans besoin d'installer aucun fichier spécial (que ce soit dans un environnement asy d'un fichier .tex ou dans un fichier .asy)
- 2 modes de compilation rapides prédéfinies pour les fichiers .tex avec environnement asy (aucune configuration à effectuer)
- possibilité aussi d'utiliser latexmk (prédéfinie aussi comme mode de "compilation rapide")
- le panneau de gauche rappelle une liste exhaustive des types et fonctions asymptotes (que l'on peut insérer en un clic)
Image
Image
Image
Texmaker (version courante : 5.0.4) : éditeur LaTeX libre et multi-plateforme avec afficheur pdf.
PdfAdd : Tableaux variations, courbes, arbres, graphes, loi binomiale, cercle trigo, suites pour pdflatex et Asymptote
Site de documentation sur LaTeX
texmaker
Kilo-utilisateur
 
Messages: 226
Inscription: Vendredi 30 Juillet 2010, 11:19
Statut actuel: Actif et salarié | Enseignant

Re: angles droits et 3D

Messagepar GMaths » Jeudi 12 Janvier 2012, 19:51

texmaker a écrit:Et avec Texmaker (3.2.2) :

Merci pour les nouveautés : je testerai le weekend prochain et ajouterai ici un tutoriel relatif à "asymptote et texmaker"... à côté de ceux que j'ai débutés sur "asymptote et notepad++" et "asymptote et texworks/latexmk".
GMaths
Exa-utilisateur
 
Messages: 2031
Inscription: Lundi 01 Octobre 2007, 09:20
Statut actuel: Actif et salarié | Enseignant

Re: Angles droits et 3D

Messagepar GMaths » Jeudi 12 Janvier 2012, 20:08

GMaths a écrit:Merci pour les nouveautés : je testerai le weekend prochain ...

J'ai tout de même installé vite fait pour voir. :-)

Est-ce une impression... ou certains mots sont-ils en caractères gras sur l'image ci-dessus : je n'ai pas le même rendu chez moi.
... et j'ai aussi notamment une couleur différente pour les types de données.

Image

Si je pouvais mettre en gras les types (à défaut de pouvoir les souligner comme ci-dessous avec notepad++)... à l'instar des mots-clés : "for", "operator", "return" qui ressortent bien sur ton image (dans le message précédent)... et qui se montrent beaucoup plus discrets chez moi (cf image ci-dessus).

Image
Dernière édition par GMaths le Vendredi 13 Janvier 2012, 07:15, édité 1 fois.
GMaths
Exa-utilisateur
 
Messages: 2031
Inscription: Lundi 01 Octobre 2007, 09:20
Statut actuel: Actif et salarié | Enseignant

Re: Angles droits et 3D

Messagepar GMaths » Jeudi 12 Janvier 2012, 21:06

J'ai relevé une autre différence par rapport à ce que l'on voit sur l'image donnée en exemple :

Chez moi, quelques types uniquement sont colorés :

Image

J'en viens à me demander... si je n'ai pas la coloration de la version précédente...
et si ma mise à jour par écrasement, sans désinstallation de la version précédente, n'est pas en cause.

-----

Edition : environ 20 minutes plus tard.

Image

Je ne saurai dire... si c'est le fait d'une désinstallation/réinstallation... ou le fait d'avoir été faire un tour dans Options/ConfigurerTexmaker/Editeur... mais la couleur des types (pour ceux qui sont colorés) devient conforme à celle qui était donnée en exemple. Par contre, les mots qui donnaient l'impression d'être en gras dans l'exemple donné... ne donnent toujours pas cette impression chez moi.

-----

Edition : environ 30 minutes plus tard.

J'obtiens quasiment ce qui était donné en exemple... à part cette chose bizarre, au delà de la différence de fonte, de l'impression de caractères gras pour certains mots à gauche (for, operator, return) que l'on n'a pas à droite.

Image

Je focalise sur cette différence... car ce serait bien de pouvoir mettre en gras (ou de souligner) certaines catégories : j'ai cette image de gauche qui laisse espérer quelque chose que je n'arrive pas à reproduire chez moi.
GMaths
Exa-utilisateur
 
Messages: 2031
Inscription: Lundi 01 Octobre 2007, 09:20
Statut actuel: Actif et salarié | Enseignant

Re: Angles droits et 3D

Messagepar GMaths » Vendredi 13 Janvier 2012, 07:21

GMaths a écrit:Je focalise sur cette différence... car ce serait bien de pouvoir mettre en gras (ou de souligner) certaines catégories : j'ai cette image de gauche qui laisse espérer quelque chose que je n'arrive pas à reproduire chez moi.

J'ai fait des essais de fontes monochasses différentes de Courier New... et il semblerait que l'on ait cette impression avec certaines fontes...
... mais, du même coup, je m'interroge encore : est-ce qu'une fausse impression de gras liée à la couleur... ou est-ce du gras disponible uniquement avec certaines fontes ?
GMaths
Exa-utilisateur
 
Messages: 2031
Inscription: Lundi 01 Octobre 2007, 09:20
Statut actuel: Actif et salarié | Enseignant

Re: Angles droits et 3D

Messagepar guiguiche » Vendredi 13 Janvier 2012, 08:48

Est-ce aussi un comportement différent de windows/linux ?
Pas d'aide par MP : les questions sont publiques, les réponses aussi.
Tu as apprécié l'aide qui t'a été fournie ? Alors n'hésite pas à rendre la pareille à quelqu'un d'autre.
Un peu d'autopromotion.
guiguiche
Modérateur
 
Messages: 8073
Inscription: Vendredi 06 Janvier 2006, 15:32
Localisation: Le Mans
Statut actuel: Actif et salarié | Enseignant

Re: Angles droits et 3D

Messagepar texmaker » Vendredi 13 Janvier 2012, 12:31

1) Avant d'installer proprement une nouvelle version de Texmaker, il faut désinstaller la précédente.
2) Le rendu des polices dépend du système d'exploitation et de la qualité des polices en question (Texmaker ne fait que déclarer que tel truc doit être de telle couleur, en gras, en italique). La police "courier new" n'a jamais été réputé pour son merveilleux rendu à l'écran (on peut trouver des fontes monospaces libres comme liberation-mono, dejavu-mono, etc... qui ont un meilleur rendu - de plus sous windows, les fontes ne sont pas forcément lissées par défaut : il faut souvent le paramétrer soi-même)
3) Si la coloration syntaxique pour les fichiers et environnements asymptote est loin d'être parfaite avec Texmaker, je rappelle (juste pour équilibrer un peu les choses) que c'est loin aussi d'être parfait ailleurs.
Exemples ci-dessous avec un environnement asymptote dans un fichier .tex avec notepad++ (qui ne reconnait pas les environnements asy dans les documents latex), Texworks et Texmaker :
Image
Image
Image
Texmaker (version courante : 5.0.4) : éditeur LaTeX libre et multi-plateforme avec afficheur pdf.
PdfAdd : Tableaux variations, courbes, arbres, graphes, loi binomiale, cercle trigo, suites pour pdflatex et Asymptote
Site de documentation sur LaTeX
texmaker
Kilo-utilisateur
 
Messages: 226
Inscription: Vendredi 30 Juillet 2010, 11:19
Statut actuel: Actif et salarié | Enseignant

Suivante

Retourner vers Asymptote

 


  • Articles en relation
    Réponses
    Vus
    Dernier message

Qui est en ligne

Utilisateurs parcourant ce forum: Aucun utilisateur enregistré et 2 invités